9e9fe1435a
… being installed. There is already most of the main code logic for this, though now plug-ins need to be in their own subdirectories, which breaks for plug-ins/common/ and plug-ins/python/, while I needed plug-ins in both these categories to generate the Windows installer welcome images (file-png, and python-fu-eval in particular). Once again, meson was not very helpful, since all its functions still refuse to output generated files in subdirectories, so I end up duplicating plug-in files with a custom Python script. This should fix the CI. It was working on my machine as GIMP was installed, but such a build rule should work even without GIMP installed. This will also be useful in the future when we'll want to run unit tests of plug-ins through the finale GIMP binary itself.
53 lines
1.3 KiB
Meson
53 lines
1.3 KiB
Meson
if not have_python
|
|
subdir_done()
|
|
endif
|
|
|
|
plugins = [
|
|
{ 'name': 'colorxhtml' },
|
|
{ 'name': 'file-openraster' },
|
|
{ 'name': 'foggify' },
|
|
{ 'name': 'gradients-save-as-css' },
|
|
{ 'name': 'histogram-export' },
|
|
{ 'name': 'palette-offset' },
|
|
{ 'name': 'palette-sort' },
|
|
{ 'name': 'palette-to-gradient' },
|
|
{ 'name': 'python-eval' },
|
|
{ 'name': 'spyro-plus' },
|
|
]
|
|
|
|
if not stable
|
|
plugins += [
|
|
{ 'name': 'test-dialog' },
|
|
]
|
|
endif
|
|
|
|
subdir('python-console')
|
|
|
|
foreach plugin : plugins
|
|
name = plugin.get('name')
|
|
srcs = plugin.get('srcs', [name + '.py'])
|
|
|
|
install_data(srcs, install_dir: gimpplugindir / 'plug-ins' / name,
|
|
install_mode: 'rwxr-xr-x')
|
|
|
|
foreach src : srcs
|
|
# Ugly trick to copy Python plug-ins into subfolders so that we can run GIMP
|
|
# from the build directory without installing it.
|
|
run_command(python, meson.project_source_root() / '.gitlab/cp-plug-in-subfolder.py',
|
|
meson.current_source_dir() / src, meson.current_build_dir() / name, check: true)
|
|
endforeach
|
|
endforeach
|
|
|
|
|
|
if python.found()
|
|
python_config = configuration_data()
|
|
python_config.set('PYTHON_PATH', python.full_path())
|
|
|
|
configure_file(
|
|
input : 'pygimp.interp.in',
|
|
output: 'pygimp.interp',
|
|
configuration: python_config,
|
|
install: true,
|
|
install_dir: gimpplugindir / 'interpreters',
|
|
)
|
|
endif
|