ca230cb770
Now that we bumped our meson requirement, meson is complaining about several features now deprecated even in the minimum required meson version: s/meson.source_root/meson.project_source_root/ to fix: > WARNING: Project targets '>=0.56.0' but uses feature deprecated since '0.56.0': meson.source_root. use meson.project_source_root() or meson.global_source_root() instead. s/meson.build_root/meson.project_build_root/ to fix: > WARNING: Project targets '>=0.56.0' but uses feature deprecated since '0.56.0': meson.build_root. use meson.project_build_root() or meson.global_build_root() instead. Fixing using path() on xdg_email and python ExternalProgram variables: > WARNING: Project targets '>=0.56.0' but uses feature deprecated since '0.55.0': ExternalProgram.path. use ExternalProgram.full_path() instead s/get_pkgconfig_variable *(\([^)]*\))/get_variable(pkgconfig: \1)/ to fix: > WARNING: Project targets '>=0.56.0' but uses feature deprecated since '0.56.0': dependency.get_pkgconfig_variable. use dependency.get_variable(pkgconfig : ...) instead
71 lines
1.4 KiB
Meson
71 lines
1.4 KiB
Meson
apptests_links = [
|
|
libappconfig,
|
|
libappactions,
|
|
libappdialogs,
|
|
libappdisplay,
|
|
libappgui,
|
|
libappmenus,
|
|
libapppropgui,
|
|
libapptools,
|
|
libappwidgets,
|
|
libgimpbase,
|
|
libgimpcolor,
|
|
libgimpconfig,
|
|
libgimpmath,
|
|
libgimpmodule,
|
|
libgimpthumb,
|
|
libgimpwidgets,
|
|
]
|
|
|
|
|
|
libapptestutils_sources = [
|
|
'gimp-app-test-utils.c',
|
|
'gimp-test-session-utils.c',
|
|
]
|
|
|
|
libapptestutils = static_library('apptestutils',
|
|
libapptestutils_sources,
|
|
dependencies: libapp_dep,
|
|
link_with: apptests_links,
|
|
)
|
|
|
|
apptests_links += libapptestutils
|
|
|
|
|
|
app_tests = [
|
|
'core',
|
|
'gimpidtable',
|
|
'save-and-export',
|
|
'session-2-8-compatibility-multi-window',
|
|
'session-2-8-compatibility-single-window',
|
|
'single-window-mode',
|
|
# 'tools',
|
|
'ui',
|
|
'xcf',
|
|
]
|
|
|
|
cmd = run_command('create_test_env.sh', check: false)
|
|
if cmd.returncode() != 0
|
|
error(cmd.stderr().strip())
|
|
endif
|
|
|
|
foreach test_name : app_tests
|
|
test_exe = executable(test_name,
|
|
'test-@0@.c'.format(test_name),
|
|
dependencies: [ libapp_dep, appstream_glib ],
|
|
link_with: apptests_links,
|
|
)
|
|
|
|
test(test_name,
|
|
test_exe,
|
|
env: [
|
|
'GIMP_TESTING_ABS_TOP_SRCDIR=' + meson.project_source_root(),
|
|
'GIMP_TESTING_ABS_TOP_BUILDDIR='+ meson.project_build_root(),
|
|
'GIMP_TESTING_PLUGINDIRS=' + meson.project_build_root()/'plug-ins'/'common',
|
|
'GIMP_TESTING_PLUGINDIRS_BASENAME_IGNORES=mkgen.pl',
|
|
'UI_TEST=yes',
|
|
],
|
|
suite: 'app',
|
|
)
|
|
|
|
endforeach
|